;  THIS PLOTS ON CALCOMP (OR TO XGP) STUFF FROM MP.DMP
	TITLE PLOTIT ; ********* MAY 9,75 *********
	EXTERNAL PLOT,PLOTS

	CH3←15	;WAS ←13  4/18/75 *******

BEG:	JSA 16,PLOTS    ;INITS PLOT PROG.
	JUMP 2	;TYPE 'C' TO CENTER PEN, AFTER YOU MOVE IT TO LEFT.

	OUTSTR[ASCIZ/FILE NAME (DEFAULT=PLT)  /]
	INCHWL 1
	CAIN	1,15		; LOOK FOR CR.
	JRST 	DFAULT
	SETZM DIR		; THE FILE NAME WILL BE HERE.
	SKIPA 2,[POINT 6,DIR]
GOT:	INCHWL	1
	CAIGE	1,60		; CHECKS FOR GOOD CHARS.
	JRST	DONE
	SUBI	1,40
	IDPB	1,2
	JRST	GOT

DFAULT:	MOVE 1,[SIXBIT/PLT/]
	MOVEM 1,DIR
DONE:	INIT CH3,17
	SIXBIT/DSK/
	0
	0
	MOVE 0,[SIXBIT/PLT/]
	MOVEM 0,DIR+1
	SETZM DIR+2
	SETZM DIR+3
	LOOKUP CH3,DIR
	JRST CENTER
	SETZM DIR+1

;*************	JRST INP

HEADER:	HRRZI 0,M		;THROW AWAY HEADER. 128 WDS.
	SUBI 0,1
	MOVEM 0,COM
	MOVNI 0,=128
	HRLM 0,COM
	INPUT CH3,COM
	STATZ CH3,740000
	0

INP:	HRRZI 0,M
	SUBI 0,1
	MOVEM 0,COM
	MOVNI 0,=128
	HRLM 0,COM
	INPUT CH3,COM
	STATZ CH3,740000
	0
	MOVEI 6,1
LUP:	MOVEI 5,M
	ADDI  5,(6)
	MOVE 2,(5)	; UNPAC ROUTINE
	LSHC 2,-10	; 14 BITS, 14 BITS, 8 BITS
	ASH 3,-34
	MOVEM 3,K 
	LSHC 2,-16
	ASH 3,-26
	MOVEM 3,J 
	LSHC 2,-16
	ASH 3,-26
	MOVEM 3,I

PLT:	JSA 16,PLOT
	JUMP I
	JUMP J
	JUMP K
	CAMGE 6,M
	AOJA 6,LUP

	MOVE 2,M
	CAIN 2,=127
	JRST INP
	EXIT
CENTER:	MOVE DIR    ;TYPE 'C' TO CENTER PEN.  YOU PUT IT TO FAR LEFT.
	CAME [SIXBIT/C/]
	HALT		;DIES IF FILE WAS NOT FOUND 
	OUTSTR[ASCIZ/CENTERING THE PEN /]
	JSA 16,PLOT
	JUMP [=3000]	;MOVES 15 INCHES TO RIGHT
	JUMP [0]
	JUMP [-3]
	INCHWL 1	;GET THE LINE FEED
	JRST BEG+2	;GO ASK FOR NAME AGAIN.
COM:	OCT 0,0
BLKNUM:	0


I:	0
J:	0
K:	0
M:	BLOCK =128

DIR:	BLOCK 4

	END BEG